Multi-Indicator CO2 System

We designed a 3-module system that is able to read, detect and indicate the levels of CO2 in interior spaces specifically homes and offices as a way to promote air pollution awareness and boost productivity and mood. One module senses the CO2 levels and sends the data to an MQTT topic that the other 2 modules can read and extrapolate the data to power their unique indication outcomes.

A light module that takes inspiration from blooming flowers and represents CO2 levels through light colours and pulsation speeds.

A window mounted module that takes inspiration from the tapping and pecking of birds and indicates to the user to open the window via repeated tapping when CO2 levels are harmful.

You’ll need:

1. SCD40 True CO2, Temperature and Humidity Sensor
2. A Strip of Neopixel Lights (cut to 9 lights)
3. A Micro-Servo
4. x3 Wemos D1 Minis (all soldered and authorised accessed to the Wi-Fi network)
5. x2-3 USB-C to Micro USB Cables
6. x2 USB-C Power Plugs (make sure they are 5V 1A)
7. A Power Bank
8. x3 Male to Male Wires
9. x7 Female to Female Wires
10. x3 Male to Female Wires
11. A Soldering Kit
12. A 3D Printer (we used the Creality Ender 3 V3 SE)
13. PLA Filament
14. A Lubricant e.g Olive Oil Spray (in case pieces aren’t initially clicking too smoothly)
15. A computer with Arduino IDE, MQTT Explorer and Creality Slicer installed

First, copy and paste the sketch attached below into Arduino IDE, making sure you have all the required Libraries.

Then, upload the sketch to your first Wemos D1 Mini via the USB-C to Micro USB Cable.

#include <Wire.h> // Library for I2C communication

#include <ESP8266WiFi.h> // ESP8266 Wi-Fi library

#include <PubSubClient.h> // MQTT client library

#include "SparkFun_SCD4x_Arduino_Library.h" // Library for SCD4x CO2 sensor

// ===================================================

// Wi-Fi and MQTT Configuration

// ===================================================

const char* ssid = "StudentResidences"; // Wi-Fi network name (SSID)

const char* mqtt_server = "test.mosquitto.org"; // MQTT broker address

const char* password = ""; // No password required for this Wi-Fi

const char* mqtt_topic = "air_qualityJack"; // MQTT topic to publish CO2 data

// ===================================================

// Initialize Wi-Fi and MQTT Clients

// ===================================================

WiFiClient espClient;

PubSubClient client(espClient);

SCD4x airSensor; // Define the SCD4x CO2 sensor

// ===================================================

// MQTT Message Callback Function

// ===================================================

/* This function is triggered whenever an MQTT message arrives.

It prints the message contents to the Serial Monitor.

*/

void callback(char* topic, byte* payload, unsigned int length) {

Serial.print("Message arrived: ");

Serial.print(topic);

Serial.print(": ");

// Print the message content

for (int i = 0; i < length; i++) {

Serial.print((char)payload[i]);

}

Serial.println();

}

// ===================================================

// Setup Function: Runs Once When the Board Starts

// ===================================================

void setup() {

Serial.begin(115200); // Start serial monitor at 115200 baud rate

// Initialize I2C communication for the SCD4X sensor

Wire.begin(D1, D2); // SDA = D1, SCL = D2

setupWiFi(); // Connect to Wi-Fi

client.setServer(mqtt_server, 1883); // Set MQTT broker address

client.setCallback(callback); // Assign callback function for MQTT messages

// Initialize SCD4X sensor

if (!airSensor.begin()) {

Serial.println("Failed to initialize SCD4X sensor. Check connections!");

while (1); // Halt execution if sensor initialization fails

}

Serial.println("SCD4X sensor initialized.");

airSensor.startPeriodicMeasurement(); // Start continuous CO2 measurements

}

// ===================================================

// Main Loop: Runs Continuously

// ===================================================

void loop() {

if (!client.connected()) {

reconnect(); // Ensure MQTT stays connected

}

client.loop(); // Handle incoming MQTT messages

// ==========================

// Read CO2 Data from Sensor

// ==========================

if (airSensor.readMeasurement()) { // Check if new sensor data is available

uint16_t co2Value = airSensor.getCO2(); // Get CO2 value in ppm

Serial.print("CO2: ");

Serial.println(co2Value); // Print CO2 level to Serial Monitor

// Publish CO2 data to MQTT topic

char payload[10];

snprintf(payload, sizeof(payload), "%d", co2Value); // Convert integer to string

client.publish(mqtt_topic, payload); // Send data to MQTT broker

} else {

Serial.println("Waiting for new SCD4X data...");

}

delay(5000); // Wait 5 seconds before next measurement

}

// ===================================================

// Wi-Fi Setup Function

// ===================================================

void setupWiFi() {

delay(10);

Serial.println();

Serial.print("Connecting to ");

Serial.println(ssid);

WiFi.begin(ssid, password); // Start Wi-Fi connection

// Wait until Wi-Fi is connected

while (WiFi.status() != WL_CONNECTED) {

delay(5000);

Serial.print(".");

}

Serial.println("\nWiFi connected");

Serial.print("IP address: ");

Serial.println(WiFi.localIP()); // Print device's IP address

}

// ===================================================

// MQTT Reconnect Function: Keeps Connection Alive

// ===================================================

void reconnect() {

while (!client.connected()) { // Loop until reconnected

Serial.print("Attempting MQTT connection...");

if (client.connect("AirQualityModule")) { // Try to connect to MQTT

Serial.println("connected");

} else {

Serial.print("failed, rc=");

Serial.print(client.state()); // Print error code if failed

Serial.println(" try again in 5 seconds");

delay(5000); // Wait before retrying

}

}

}

Now, wire the SCD40 component to the Wemos D1 Mini with 4 Female to Female Wires.

Connect like so (SCD40 on the left, Wemos D1 Mini on the right)

GND -> GND

VDD -> 3V3 (it is key that it is the 3V3 NOT the 5V)

SCL -> D2

SDA -> D1

Now, you should be seeing CO2 readings in the Serial Monitor and if you open the MQTT Explorer and go to the mosquitto client and search the air_qualityJack topic, you can see the readings updating there as well.

Now, open each STL file attached below one at a time. First let’s do the lid, orientate the model so that the underside is facing upwards as this’ll make it so no supports are needed.

Then, in the settings set the Infill Type to Gyroid and the Infill Density to around 20%, these’ll give us the fastest printing speeds without sacrificing mechanical properties.

Now, slice the model and import it to the SD card that comes with the printer.

Now, print the model on your 3D printer and take it off once it’s finished and cooled.

Repeat the process once more with the bottom piece, make sure it is oriented with the top facing upwards.

Now, that you have your electronics wired and your parts printed, it’s now time to assemble.

First, unplug the electronics from the computer and feed the cable through the designated cable hole in the container piece, making sure the electronics are inside the container.

Now, place the lid on top, making sure it’s flush with the top of the container and twist right to lock it into place.

If it’s giving you some trouble, spray some Olive Oil into the locking mechanism pieces and try again, once it’s able to smoothly lock and unlock, just wipe off the spray.

First, copy and paste the sketch attached below into Arduino IDE, making sure you have all the required Libraries.

Then, upload the sketch to your second Wemos D1 Mini via another USB-C to Micro USB Cable.

#include <ESP8266WiFi.h> // Library for Wi-Fi connectivity

#include <PubSubClient.h> // Library for MQTT communication

#include <Adafruit_NeoPixel.h> // Library for controlling NeoPixel LED strips

// ============================

// Wi-Fi and MQTT Configuration

// ============================

const char* ssid = "StudentResidences"; // Wi-Fi SSID (No password)

const char* mqtt_server = "test.mosquitto.org"; // Replace with your MQTT broker's IP

const char* mqtt_topic = "air_qualityJack"; // MQTT topic for CO2 sensor data

// ============================

// Initialize Wi-Fi and MQTT Client

// ============================

WiFiClient espClient;

PubSubClient client(espClient);

// ============================

// NeoPixel Configuration

// ============================

Adafruit_NeoPixel strip = Adafruit_NeoPixel(9, D4, NEO_GRB + NEO_KHZ800);

// 9 LEDs, connected to D4, using GRB color order

// ============================

// Global Variables

// ============================

int co2Value = 0; // Stores CO2 ppm received from MQTT

int pulseValue = 0; // Controls the breathing effect (0-100)

bool increasing = true; // Determines if brightness is increasing or decreasing

// ===================================================

// Setup Function: Runs Once When the Board Starts

// ===================================================

void setup() {

Serial.begin(115200); // Start serial monitor for debugging

WiFi.begin(ssid); // Connect to Wi-Fi

while (WiFi.status() != WL_CONNECTED) {

delay(500);

Serial.print("."); // Print dots until connected

}

Serial.println("Connected to WiFi");

client.setServer(mqtt_server, 1883); // Set MQTT broker

client.setCallback(callback); // Assign callback function to handle messages

strip.begin(); // Initialize the LED strip

strip.show(); // Ensure all LEDs are turned off initially

}

// ===================================================

// Main Loop: Runs Continuously

// ===================================================

void loop() {

if (!client.connected()) {

reconnect(); // Reconnect to MQTT if disconnected

}

client.loop(); // Process MQTT messages

updateLEDs(co2Value); // Update LEDs based on CO2 value

delay(20); // Small delay for smoother pulsing effect

}

// ===================================================

// MQTT Callback: Handles Incoming Messages

// ===================================================

void callback(char* topic, byte* payload, unsigned int length) {

payload[length] = '\0'; // Ensure payload is a null-terminated string

String payloadString = String((char*)payload); // Convert payload to string

co2Value = payloadString.toInt(); // Convert string to integer (CO2 ppm)

Serial.print("Received CO2 value: ");

Serial.println(co2Value);

}

// ===================================================

// MQTT Reconnect Function: Keeps the Connection Alive

// ===================================================

void reconnect() {

while (!client.connected()) { // Keep trying until connected

if (client.connect("WemosD1Mini")) {

client.subscribe(mqtt_topic); // Subscribe to the topic after successful connection

} else {

delay(5000); // Wait 5 seconds before retrying

}

}

}

// ===================================================

// LED Update Function: Handles Colors & Pulsing Effect

// ===================================================

void updateLEDs(int co2) {

int redValue = 0;

int greenValue = 0;

int blueValue = 0;

int pulseSpeed;

// ==========================

// Determine LED Color Based on CO2 Levels

// ==========================

if (co2 <= 1000) {

// Smooth transition from Green to Yellow (Safe Zone)

greenValue = map(co2, 0, 1000, 255, 255); // Green stays at full brightness

redValue = map(co2, 0, 1000, 0, 255); // Red increases gradually

pulseSpeed = 4; // Slow breathing effect in the safe zone

} else {

// Smooth transition from Yellow to Red (Danger Zone)

redValue = map(co2, 1000, 2000, 255, 255); // Red stays at full brightness

greenValue = map(co2, 1000, 2000, 255, 0); // Green decreases gradually

pulseSpeed = 1; // Faster pulse in danger zone

}

// ==========================

// Create Pulsating Effect

// ==========================

if (increasing) {

pulseValue += pulseSpeed; // Increase brightness

if (pulseValue >= 100) increasing = false; // Reverse at peak

} else {

pulseValue -= pulseSpeed; // Decrease brightness

if (pulseValue <= 10) increasing = true; // Reverse at low point

}

// Scale brightness to create pulsing effect (range: 50 - 255)

int brightness = map(pulseValue, 0, 100, 50, 255);

// Apply brightness scaling to LED colors

redValue = (redValue * brightness) / 255;

greenValue = (greenValue * brightness) / 255;

blueValue = (blueValue * brightness) / 255;

// ==========================

// Update All LEDs in the Strip

// ==========================

for (int i = 0; i < strip.numPixels(); i++) {

strip.setPixelColor(i, strip.Color(redValue, greenValue, blueValue));

}

strip.show(); // Refresh LED colors

}

First, using your soldering kit, solder the 3 Male to Male Wires to the Neopixel Strip, making sure they are safely and securely connected to the strip.

Now, wire the soldered Neopixel Strip component to the Wemos D1 Mini with 3 Female to Female Wires.

Connect like so (Neopixel Strip on the left, Wemos D1 Mini on the right)

GND -> GND

5V -> 5V

Din -> D4

Now, if you have the Air Sensor Module plugged in you should see the Neopixel Strip pulsating slowly and should be lime green colour.

Now, open each STL file attached below one at a time. First, let’s do the Base, orientate the model so that the topside is facing upwards as this’ll make it so no supports are needed.

Then, in the settings set the Infill Type to Gyroid and the Infill Density to around 40%, these’ll give us the fastest printing speeds without sacrificing mechanical properties.

Now, slice the model and import it to the SD card that comes with the printer.

Now, print the model on your 3D printer and take it off once it’s finished and cooled.

Repeat the process with all the other pieces, this will take a long time…

(REMINDER: you’ll need to have 10 Fin Pins and 10 Fins as well as the Retaining Rings need to be printed 2 times)

Once you have all your pieces printed it’s time to start assembling.

First, place the Gear inside the Base, making sure the lever of the Gear is all the way to the right.

Then, insert the 10 Fin Pins into the holes of the Base, making sure they line up with the Gear and the flat side of the Fin Pins are facing outwards in a circular position.

To test, push the Gear lever to the left, this’ll spin all the Fin Pins around, if the spinning is a little jittery or janky, spray some Olive Oil like we did for the Air Sensor Module. Wipe the spray off once function is running smoothly and reset the Gear back to the right.

Now that you have the Base, Gear and Fin Pins assembled, it’s time to place the Cover on top, making sure it’s flush with the top of the Base.

Next, you can add all the Fins into the Fin Pins now, make sure the Fins are pointing to the right and generally line up with the Base’s circumference.

To test, push the Gear lever to the left, this’ll spin all the Fins around. If everything’s running smoothly, simply reset the Gear back to the right.

Now to add the Retaining Rings and the Shade.

Push the Gear to the left around halfway, this’ll give us some space to place the first Retaining Ring inside. Carefully lower the Retaining Ring down to the bottom of the module, you should see a pin on each of the Fins, that is where the Retaining Ring must connect to. Swivel the Retaining Ring so that it properly hovers above the pins and place it on top.

Now you can add the Shade on top of said Retaining Ring with the designated 5 pins on it. Once that’s slotted in, you can add the second Retaining Ring on top, doing the same swivelling technique like last time, line up the holes of the Retaining Ring to the pins in the top of each Fin and line up the designated 5 pins to the holes in the Shade. Slot it in place and now everything should be secured.

Now you can open and close the Fins smoothly and securely.

Now that everything’s essentially assembled, it’s time to add the electronics to the Module. First connect the end of the Neopixel Strip (the end without the wires) to the lip of the Lid (you can use superglue, etc. I used cello tape for this demonstration).

Then, carefully lower the Lid down with the electronics hanging underneath through the middle of the Module, making sure the electronics don’t get caught it anything.

Then feed the USB-C to Micro USB Cable through the designated cable hole in the Base and plug it into a Power Plug.

Everything should be working and you now have a Light Indicator Module that is able to present the CO2 level through coloured lights.

First, copy and paste the sketch attached below into Arduino IDE, making sure you have all the required Libraries.

Then, upload the sketch to your third Wemos D1 Mini via either USB-C to Micro USB Cable that has been unplugged from one of the other modules or a third one.

#include <ESP8266WiFi.h>

#include <MQTT.h>

#include <Servo.h>

const char ssid[] = "StudentResidences";

const char pass[] = "";

const char myBroker[] = "test.mosquitto.org";

int airQuality = 0;

Servo myServo; // create servo object to control a servo

WiFiClient net;

MQTTClient client;

unsigned long lastMillis = 0;

void connect() {

Serial.print("checking wifi...");

while (WiFi.status() != WL_CONNECTED) {

Serial.print(".");

delay(1000);

}

Serial.print("\nconnecting...");

//set your own client ID

while (!client.connect("air_qualityJack", "", "")) {

Serial.print(".");

delay(1000);

}

Serial.println("\nconnected!");

client.subscribe("air_qualityJack");

// client.unsubscribe("/hello");

}

//messageReceived runs constantly - whenever the value on the broker changes, it updates on the client immediately

void messageReceived(String &topic, String &payload) {

Serial.println("incoming: " + topic + " - " + payload);

airQuality = payload.toInt(); //convert the payload to an integer (if it actually is an integer)

}

void setup() {

myServo.attach(D5, 500, 2400); // attaches the servo on pin D5 to the servo object

Serial.begin(115200);

WiFi.begin(ssid, pass);

client.begin(myBroker, net);

client.onMessage(messageReceived);

connect();

}

void loop() {

client.loop();

delay(10);

if (!client.connected()) {

connect();

}

knock();

}

void knock() {

if (airQuality <= 1000) {

myServo.write(90); // Return servo to neutral position

} else if (airQuality > 1001) {

// Stop knocking

myServo.write(180); // tell servo to go to position in variable 'pos'

delay(200);

myServo.write(90);

delay(200);

}

}

Now, wire the Micro-Servo component to the Wemos D1 Mini with 4 Female to Female Wires.

Connect like so (Micro-Servo on the left, Wemos D1 Mini on the right)

Brown -> GND

Red -> 5V

Yellow -> D5

Also, you can hook up the electronics to a Power Bank as this module requires to be lightweight and high up (inaccessible for Power Plug)

Now, if you blow into the Air Sensor Module to force it to read a high enough CO2 reading then the Micro Servo should start moving back and forth until the readings reach a healthy CO2 reading.

Now, open each STL file attached below one at a time. First, let’s do the Servo Arm, you’ll need to add some supports below this piece as there is no flat side to it to lay on the print bed. Use the Automatic Support feature.

Then, in the settings set the Infill Type to Gyroid and the Infill Density to 100%, as this print is very small and will be used heavily, it’s best it has the greatest density.

Now, slice the model and import it to the SD card that comes with the printer.

Now, print the model on your 3D printer and take it off once it’s finished and cooled.

For the Bird model, you’ll want to set the Infill Density to 0%, as this’ll be hollow. To go along with this, set the Infill Wall amount to around 5-6 for good structure and also set the Floor Wall off, since we want an open bottom.

Now, slice the model and import it to the SD card that comes with the printer.

Now, print the model on your 3D printer and take it off once it’s finished and cooled.

Now that we have the parts printed, it is time for assembly.

First, attach the printed Servo Arm to the Micro Server.

Then, glue the Micro Servo components to the underside of the Bird.

After that’s done, you’ll need to make your own container approximately 30mm tall, 70mm wide and 120mm long. This will serve as the storage space to hide all the other components such as the Power Bank. Remember to leave a hole to allow for the Power Bank to be charged.

Lastly, glue the Bird segment to the box and stick it to the window.

Everything should be working and you now have a Window Indicator Module that is able to warn the user of high CO2 levels and promote them to open the window.

You should now have a fully functioning 3-module system that is able to read, detect and indicate the levels of CO2 in interior spaces. You can choose whether you want the Light Indicator Module active or the Window Indicator Module to be activated, or you could have both active.