How to Make AI Pin | Real Life Jarvis

by Shahbaz Hashmi Ansari in Circuits > Wearables

83 Views, 0 Favorites, 0 Comments

How to Make AI Pin | Real Life Jarvis

How to Make *AI Pin* | Real Life Jarvis (Student Project!)
20250820_150225.png

Greetings everyone, and welcome to my Instructables tutorial. Today, I'll guide you through the process of creating an AI Pin.

Project Overview:

This project is built using the Seeed Studio XIAO ESP32S3 Sense board. It connects with a Telegram bot to receive commands and interact with the user. Once a query is sent, the device captures an image and forwards it along with the question to the Gemini AI API. The response is then delivered back to the user directly on Telegram. This is a great project for students, as it combines IoT and AI concepts, making it perfect for hands-on learning and even as a college project.

From a technical perspective, the ESP32S3 Sense is configured to use its onboard camera for capturing images. It connects to Wi-Fi, communicates with Telegram servers, and handles secure HTTPS requests to Google’s Gemini API. Base64 encoding is used to transfer image data along with the text query. The code manages camera frames, parses API responses using ArduinoJson, and sends AI-generated replies to Telegram. This setup demonstrates practical integration of hardware, networking, and AI services in a compact IoT system.

Before beginning, a huge shoutout to JLCMC for sponsoring.

Now, let's get started with our project!

Supplies

Screenshot (937).png
Screenshot (938).png
Screenshot (939).png

Electronic Components Required:

  1. Seeed Studio XIAO ESP32S3 SENSE
  2. 3.7V LI-PO Battery (400 mAh)
  3. Slide Switch
  4. Cardboard / Acrylic Sheet / Sun Board, etc.

Additional Tools:

  1. Hot Glue
  2. Cutter
  3. Soldering Iron

Software:

  1. Arduino IDE

Arduino IDE Set-up + Telegram Bot

Screenshot 2025-08-24 084335.png
Screenshot (940).png
Screenshot (941).png
Screenshot (942).png
Screenshot (943).png
Screenshot (944).png
Screenshot (947).png
Screenshot (948).png

For Arduino IDE Setup Follow these steps:

  1. Open Arduino IDE on your computer.
  2. Go to File > Preferences.
  3. In the Additional Board Manager URLs field, paste this link:
https://raw.githubusercontent.com/espressif/arduino-esp32/gh-pages/package_esp32_index.json
  1. Then click OK.
  2. Next, go to Tools > Board > Board Manager.
  3. Search for ESP32, then click Install.

Now install the required library:

  1. Open Sketch > Include Library > Manage Libraries.
  2. Search for UniversalTelegramBot.h.
  3. Install it.

Create a Telegram Bot:

  1. Open the Telegram app on your phone.
  2. Search for @BotFather (the official Telegram bot creator).
  3. Start a chat and type /newbot.
  4. Give your bot a name and a unique username.
  5. BotFather will generate a token for your bot. (Copy and save this token; we will use it in the Arduino code.)

Part 1: Basic Coding

Screenshot (951).png
Screenshot (950).png

About this step:

we’ll write a code that allows our Telegram bot to take a command from the user and reply with a simple pre-set message

Code:

#include <WiFi.h>
#include <WiFiClientSecure.h>
#include <UniversalTelegramBot.h>

// ============ Replace these with your details ============
const char* ssid = "WIFI_NAME";
const char* password = "WIFI_PASSWORD";

const char* botToken = "TELEGRAM_BOT_TOKEN"; // Your Telegram Bot Token
// ========================================================

// Setup secure WiFi client for HTTPS
WiFiClientSecure netClient;
UniversalTelegramBot bot(botToken, netClient);

unsigned long lastCheckTime = 0;
const unsigned long checkInterval = 1000;

void setup() {
Serial.begin(115200);

// Wi-Fi connect
WiFi.begin(ssid, password);
Serial.print("Connecting to WiFi");
while (WiFi.status() != WL_CONNECTED) {
delay(500);
Serial.print(".");
}
Serial.println("\nConnected.");

netClient.setInsecure();

Serial.println("Telegram Bot started.");
}

void loop() {
// Periodically check for new messages
if (millis() - lastCheckTime >= checkInterval) {
checkTelegramBot();
lastCheckTime = millis();
}
}

void checkTelegramBot() {
int numNewMessages = bot.getUpdates(bot.last_message_received + 1);

while (numNewMessages) {
for (int i = 0; i < numNewMessages; i++) {
String chat_id = String(bot.messages[i].chat_id);
String text = bot.messages[i].text;

Serial.print("Received: "); Serial.println(text);

if (text == "/ask") {
String response = "Hello, bro!";
bot.sendMessage(chat_id, response, "");
Serial.println("Sent reply: Hello, bro!");
}
}
numNewMessages = bot.getUpdates(bot.last_message_received + 1);
}
}

Connect the board to your computer using a USB-C cable. With the Arduino IDE open and your code ready, ensure you have selected the correct board and port by navigating to the Tools menu. Then, click the Upload button (the right-arrow icon) to begin compiling and flashing the sketch to the XIAO ESP32S3.

Breakdown:

1. Wi-Fi & Bot Credentials:

const char* ssid = "WIFI_NAME";
const char* password = "WIFI_PASSWORD";
const char* botToken = "TELEGRAM_BOT_TOKEN";

Replace these with your actual Wi-Fi name & password.

botToken → This is the unique key you got from BotFather on Telegram.

2. Checking Telegram Messages:

void checkTelegramBot() {
int numNewMessages = bot.getUpdates(bot.last_message_received + 1);

while (numNewMessages) {
for (int i = 0; i < numNewMessages; i++) {
String chat_id = String(bot.messages[i].chat_id);
String text = bot.messages[i].text;

Serial.print("Received: "); Serial.println(text);

if (text == "/ask") {
String response = "Hello, bro!";
bot.sendMessage(chat_id, response, "");
Serial.println("Sent reply: Hello, bro!");
}
}
numNewMessages = bot.getUpdates(bot.last_message_received + 1);
}
}

`bot.getUpdates(...)` → Checks if there are new messages.

`while (numNewMessages)` → Runs as long as there are new messages.

👉 If someone sends /ask, the bot replies:

Hello, bro!

and prints confirmation on the Serial Monitor.

Elevate Your Electronic Projects - JLCMC

Screenshot (952).png
Screenshot (953).png
Screenshot (954).png

JLCMC is your one-stop shop for all electronic manufacturing needs, offering an extensive catalog of nearly 600,000 SKUs that cover hardware, mechanical, electronic, and automation components. Their commitment to guaranteeing genuine products, rapid shipping (with most in-stock items dispatched within 24 hours), and competitive pricing truly sets them apart. In addition, their exceptional customer service ensures you always get exactly what you need to bring your projects to life.

They have everything you need for your next project:

  1. Custom Linear Guide Shafts: Precision-engineered for applications like 3D printing, CNC machines, and industrial automation.
  2. Aluminum Profiles: Versatile, durable framing solutions—perfect for machine enclosures, workstations, and custom assemblies.

To show their support for our community, JLCMC is offering an exclusive $70 discount coupon. This is the perfect opportunity to save on high-quality components for your next project. Don’t miss out—visit https://jlcmc.com/?from=RBL to explore their amazing range of products and grab your discount coupon today!

Part 2: AI Model

Screenshot (957).png
Screenshot (958).png
Screenshot (959).png
Screenshot (960).png
Screenshot (955).png
Screenshot (956).png

About this step:

We’ll upgrade that same code so the bot can use an AI model to reply with intelligent responses.

Follow these steps to create the Gemini API key:

  1. Open your browser and go to https://aistudio.google.com/
  2. Click the Create API key button. You can create a key in a new or existing Google Cloud project.
  3. The system will generate a new API key. Click the Copy button to save it. Paste the key into the designated placeholder in the code.

Code:

#include <WiFi.h>
#include <WiFiClientSecure.h>
#include <UniversalTelegramBot.h>
#include <ArduinoJson.h>

// ==== CONFIG ====
const char* ssid = "WIFI_NAME";
const char* password = "WIFI_PASSWORD";

const char* botToken = "TELEGRAM_BOT_TOKEN"; // Your Telegram Bot Token
const char* GEMINI_API_KEY = "GEMINI_API_KEY"; // Gemini API Key
// ================

// Telegram bot client
WiFiClientSecure netClient;
UniversalTelegramBot bot(botToken, netClient);

unsigned long lastCheckTime = 0;
const unsigned long checkInterval = 1000;

bool waitingForQuery = false;

String callGeminiAPI(String userPrompt) {
WiFiClientSecure client;
client.setInsecure();

if (!client.connect("generativelanguage.googleapis.com", 443)) {
Serial.println("❌ Gemini API connection failed");
return "Error: Could not connect to Gemini API";
}

// Create JSON payload
String payload = "{";
payload += "\"contents\":[{\"role\":\"user\",\"parts\":[{\"text\":\"" + userPrompt + "\"}]}],";
payload += "\"generationConfig\":{\"thinkingConfig\":{\"thinkingBudget\":-1}},";
payload += "\"tools\":[{\"googleSearch\":{}}]";
payload += "}";

// Send POST request
String url = "/v1beta/models/gemini-2.5-flash:generateContent?key=" + String(GEMINI_API_KEY);
client.println("POST " + url + " HTTP/1.1");
client.println("Host: generativelanguage.googleapis.com");
client.println("Content-Type: application/json");
client.println("Content-Length: " + String(payload.length()));
client.println("Connection: close");
client.println();
client.print(payload);

while (client.connected() && !client.available()) delay(10);

String response;
while (client.available()) {
response += client.readString();
}


Serial.println("📩 Raw Gemini Response:");
Serial.println(response);

int jsonStart = response.indexOf("\r\n\r\n");
if (jsonStart == -1) return "Error: No JSON found";
String chunkedBody = response.substring(jsonStart + 4);

String jsonBody;
int pos = 0;
while (pos < chunkedBody.length()) {
int crlf = chunkedBody.indexOf("\r\n", pos);
if (crlf == -1) break;

String sizeStr = chunkedBody.substring(pos, crlf);
int chunkSize = strtol(sizeStr.c_str(), NULL, 16);
if (chunkSize == 0) break;

jsonBody += chunkedBody.substring(crlf + 2, crlf + 2 + chunkSize);

pos = crlf + 2 + chunkSize + 2;
}

StaticJsonDocument<4096> doc;
DeserializationError error = deserializeJson(doc, jsonBody);
if (error) {
Serial.println("❌ JSON parse failed: " + String(error.c_str()));
return "Error: Could not parse JSON";
}

if (doc["candidates"][0]["content"]["parts"][0]["text"].is<String>()) {
return doc["candidates"][0]["content"]["parts"][0]["text"].as<String>();
}

return "Error: No text found";
}

void setup() {
Serial.begin(115200);

WiFi.begin(ssid, password);
Serial.print("Connecting to WiFi");
while (WiFi.status() != WL_CONNECTED) {
delay(500);
Serial.print(".");
}
Serial.println("\n✅ WiFi connected!");

netClient.setInsecure();
}

void loop() {
if (millis() - lastCheckTime >= checkInterval) {
checkTelegramBot();
lastCheckTime = millis();
}
}

void checkTelegramBot() {
int numNewMessages = bot.getUpdates(bot.last_message_received + 1);

while (numNewMessages) {
for (int i = 0; i < numNewMessages; i++) {
String chat_id = String(bot.messages[i].chat_id);
String text = bot.messages[i].text;

Serial.print("📨 Received: ");
Serial.println(text);

if (text == "/ask") {
bot.sendMessage(chat_id, "Send me your query", "");
waitingForQuery = true; // set state
}
else if (waitingForQuery) {
waitingForQuery = false; // reset state
bot.sendMessage(chat_id, "⏳ Thinking...", "");

String geminiResponse = callGeminiAPI(text);
bot.sendMessage(chat_id, geminiResponse, "");
}
}
numNewMessages = bot.getUpdates(bot.last_message_received + 1);
}
}

Copy and replace this code with your existing code in the Arduino IDE, and then click the Upload button.

Breakdown:

1. Gemini Credentials:

const char* GEMINI_API_KEY = "GEMINI_API_KEY";

GEMINI_API_KEY comes from Google AI Studio (Gemini API).

2. Gemini API Function:

String callGeminiAPI(String userPrompt) {
WiFiClientSecure client;
client.setInsecure();

if (!client.connect("generativelanguage.googleapis.com", 443)) {
return "Error: Could not connect to Gemini API";
}
  1. Connects securely to Gemini’s API server.
  2. If connection fails → returns error.

Payload Creation:

String payload = "{";
payload += "\"contents\":[{\"role\":\"user\",\"parts\":[{\"text\":\"" + userPrompt + "\"}]}],";
payload += "\"generationConfig\":{\"thinkingConfig\":{\"thinkingBudget\":-1}},";
payload += "\"tools\":[{\"googleSearch\":{}}]";
payload += "}";
  1. This is the JSON request Gemini expects.
  2. Sends the user’s message (userPrompt) to Gemini.
  3. Includes configs like thinkingBudget and googleSearch tool.

Send Request:

String url = "/v1beta/models/gemini-2.5-flash:generateContent?key=" + String(GEMINI_API_KEY);
client.println("POST " + url + " HTTP/1.1");
...
client.print(payload);

Sends an HTTPS POST request with the user’s query to Gemini API.

Image Capture

Screenshot (961).png
Screenshot (962).png
Screenshot (963).png
Screenshot (964).png

In this step, our goal is to capture an image when the bot receives a command, then convert it into Base64 format, and finally, send back the first 50 characters as confirmation.

Steps to enable the PSRAM:

Before uploading the code to your ESP32 board, you need to enable PSRAM (external memory).

  1. In the Arduino IDE, go to the Tools menu.
  2. Find the option “PSRAM”
  3. Set it to “Enabled”

✅ This ensures your ESP32 has enough memory to handle Image Capture & Gemini API responses.

Code:

#include "esp_camera.h"
#include <WiFi.h>
#include "base64.h"
#include <WiFiClientSecure.h>
#include <UniversalTelegramBot.h>

// Pin definitions for XIAO ESP32S3 Sense
#define PWDN_GPIO_NUM -1
#define RESET_GPIO_NUM -1
#define XCLK_GPIO_NUM 10
#define SIOD_GPIO_NUM 40
#define SIOC_GPIO_NUM 39
#define Y9_GPIO_NUM 48
#define Y8_GPIO_NUM 11
#define Y7_GPIO_NUM 12
#define Y6_GPIO_NUM 14
#define Y5_GPIO_NUM 16
#define Y4_GPIO_NUM 18
#define Y3_GPIO_NUM 17
#define Y2_GPIO_NUM 15
#define VSYNC_GPIO_NUM 38
#define HREF_GPIO_NUM 47
#define PCLK_GPIO_NUM 13

// ============ Replace these with your details ============
const char* ssid = "WIFI_NAME";
const char* password = "WIFI_PASSWORD";

const char* botToken = "TELEGRAM_BOT_TOKEN"; // Your Telegram Bot Token
// ========================================================

WiFiClientSecure netClient;
UniversalTelegramBot bot(botToken, netClient);

unsigned long lastCheckTime = 0;
const unsigned long checkInterval = 1000;

String handleCapture() {
camera_fb_t * fb = esp_camera_fb_get();
if(!fb) {
Serial.println("Camera capture failed");
return "Camera capture failed!";
}

// Convert image to base64
String base64String = base64::encode(fb->buf, fb->len);
// Return the frame buffer
esp_camera_fb_return(fb);
// Send base64 string
return (base64String);
}


void setup() {
Serial.begin(115200);
Serial.println();

// Camera configuration
camera_config_t config;
config.ledc_channel = LEDC_CHANNEL_0;
config.ledc_timer = LEDC_TIMER_0;
config.pin_d0 = Y2_GPIO_NUM;
config.pin_d1 = Y3_GPIO_NUM;
config.pin_d2 = Y4_GPIO_NUM;
config.pin_d3 = Y5_GPIO_NUM;
config.pin_d4 = Y6_GPIO_NUM;
config.pin_d5 = Y7_GPIO_NUM;
config.pin_d6 = Y8_GPIO_NUM;
config.pin_d7 = Y9_GPIO_NUM;
config.pin_xclk = XCLK_GPIO_NUM;
config.pin_pclk = PCLK_GPIO_NUM;
config.pin_vsync = VSYNC_GPIO_NUM;
config.pin_href = HREF_GPIO_NUM;
config.pin_sccb_sda = SIOD_GPIO_NUM;
config.pin_sccb_scl = SIOC_GPIO_NUM;
config.pin_pwdn = PWDN_GPIO_NUM;
config.pin_reset = RESET_GPIO_NUM;
config.xclk_freq_hz = 20000000;
config.frame_size = FRAMESIZE_SVGA;
config.pixel_format = PIXFORMAT_JPEG;
config.grab_mode = CAMERA_GRAB_WHEN_EMPTY;
config.fb_location = CAMERA_FB_IN_PSRAM;
config.jpeg_quality = 12;
config.fb_count = 1;

if(psramFound()){
config.jpeg_quality = 10;
config.fb_count = 2;
config.grab_mode = CAMERA_GRAB_LATEST;
} else {
config.frame_size = FRAMESIZE_VGA;
config.fb_location = CAMERA_FB_IN_DRAM;
}

// Initialize camera
esp_err_t err = esp_camera_init(&config);
if (err != ESP_OK) {
Serial.printf("Camera init failed with error 0x%x", err);
return;
}

// Wi-Fi connect
WiFi.begin(ssid, password);
Serial.print("Connecting to WiFi");
while (WiFi.status() != WL_CONNECTED) {
delay(500);
Serial.print(".");
}
Serial.println("\nConnected.");

netClient.setInsecure();

Serial.println("Telegram Bot started.");
}

void checkTelegramBot() {
int numNewMessages = bot.getUpdates(bot.last_message_received + 1);

while (numNewMessages) {
for (int i = 0; i < numNewMessages; i++) {
String chat_id = String(bot.messages[i].chat_id);
String text = bot.messages[i].text;

Serial.print("Received: "); Serial.println(text);

if (text == "/ask") {
String response = handleCapture();
Serial.println(response);
response = response.substring(0, min((int)response.length(), 50));
bot.sendMessage(chat_id, response, "");
Serial.println("Sent reply (first 50 chars of base64)");
}
}
numNewMessages = bot.getUpdates(bot.last_message_received + 1);
}
}

void loop() {
if (millis() - lastCheckTime >= checkInterval) {
checkTelegramBot();
lastCheckTime = millis();
}
}


Upload and Test the Code

  1. Connect your XIAO ESP32S3 board to your computer.
  2. Click the Upload button in the Arduino IDE to flash the code.
  3. Once uploaded, open the Serial Monitor (set baud rate to 115200).
  4. Watch the output to confirm that the XIAO ESP32S3 connects to Wi-Fi and starts the bot.

Final Match

Screenshot (965).png

Now it’s time to combine everything. This new code merges Step 4 and Step 5.

Here’s how it works: The bot first asks for a query. Once the user sends it, the XIAO ESP32S3 captures an image, converts it into Base64, and, along with the user query, sends it to the Gemini API. The API processes both inputs and returns a detailed reply.

Final Code:


#include "esp_camera.h"
#include <WiFi.h>
#include <WiFiClientSecure.h>
#include <base64.h>
#include <UniversalTelegramBot.h>
#include <ArduinoJson.h>


// Pin definitions for XIAO ESP32S3 Sense
#define PWDN_GPIO_NUM -1
#define RESET_GPIO_NUM -1
#define XCLK_GPIO_NUM 10
#define SIOD_GPIO_NUM 40
#define SIOC_GPIO_NUM 39
#define Y9_GPIO_NUM 48
#define Y8_GPIO_NUM 11
#define Y7_GPIO_NUM 12
#define Y6_GPIO_NUM 14
#define Y5_GPIO_NUM 16
#define Y4_GPIO_NUM 18
#define Y3_GPIO_NUM 17
#define Y2_GPIO_NUM 15
#define VSYNC_GPIO_NUM 38
#define HREF_GPIO_NUM 47
#define PCLK_GPIO_NUM 13


// ==== CONFIG ====
const char* ssid = "WIFI_NAME";
const char* password = "WIFI_PASSWORD";

const char* botToken = "TELEGRAM_BOT_TOKEN"; // Your Telegram Bot Token
const char* GEMINI_API_KEY = "GEMINI_API_KEY"; // Gemini API Key
// ================


WiFiClientSecure netClient;
UniversalTelegramBot bot(botToken, netClient);

unsigned long lastCheckTime = 0;
const unsigned long checkInterval = 1000;

bool waitingForQuery = false;

// Function to handle image capture and return base64 string
String handleCapture() {
camera_fb_t* fb = esp_camera_fb_get();
if (!fb) {
Serial.println("Camera capture failed");
return "Camera capture failed!";
}

String base64String = base64::encode(fb->buf, fb->len);

esp_camera_fb_return(fb);

return (base64String);
}

String callGeminiAPI(String userPrompt, String image) {
WiFiClientSecure client;
client.setInsecure();
Serial.println("prompt: "+ userPrompt + "\nimage:"+ image);

if (!client.connect("generativelanguage.googleapis.com", 443)) {
Serial.println("❌ Gemini API connection failed");
return "Error: Could not connect to Gemini API";
}

// Create JSON payload
String payload = "{";
payload += "\"contents\":[{" "\"role\":\"user\"," "\"parts\":[{" "\"inlineData\":{" "\"mimeType\":\"image/jpeg\"," "\"data\":\"" + image + "\"" "}}," "{" "\"text\":\"" + userPrompt + "\"" "}" "]" "}]," "\"generationConfig\":{\"thinkingConfig\":{\"thinkingBudget\":-1}}," "\"tools\":[{\"googleSearch\":{}}]" "}";


// Send POST request
String url = "/v1beta/models/gemini-2.5-flash:generateContent?key=" + String(GEMINI_API_KEY);
client.println("POST " + url + " HTTP/1.1");
client.println("Host: generativelanguage.googleapis.com");
client.println("Content-Type: application/json");
client.println("Content-Length: " + String(payload.length()));
client.println("Connection: close");
client.println();
client.print(payload);

Serial.println("\n\nPayload length" + String(payload.length()));
Serial.println("\n\nPayload" + payload);

while (client.connected() && !client.available()) delay(10);

String response;
while (client.available()) {
response += client.readString();
}

Serial.println("📩 Raw Gemini Response:");
Serial.println(response);

int jsonStart = response.indexOf("\r\n\r\n");
if (jsonStart == -1) return "Error: No JSON found";
String chunkedBody = response.substring(jsonStart + 4);

String jsonBody;
int pos = 0;
while (pos < chunkedBody.length()) {
int crlf = chunkedBody.indexOf("\r\n", pos);
if (crlf == -1) break;

String sizeStr = chunkedBody.substring(pos, crlf);
int chunkSize = strtol(sizeStr.c_str(), NULL, 16);
if (chunkSize == 0) break;

jsonBody += chunkedBody.substring(crlf + 2, crlf + 2 + chunkSize);

pos = crlf + 2 + chunkSize + 2;
}

StaticJsonDocument<4096> doc;
DeserializationError error = deserializeJson(doc, jsonBody);
if (error) {
Serial.println("❌ JSON parse failed: " + String(error.c_str()));
return "Error: Could not parse JSON";
}

if (doc["candidates"][0]["content"]["parts"][0]["text"].is<String>()) {
return doc["candidates"][0]["content"]["parts"][0]["text"].as<String>();
}

return "Error: No text found";
}

void setup() {
Serial.begin(115200);
Serial.println();

// Camera configuration
camera_config_t config;
config.ledc_channel = LEDC_CHANNEL_0;
config.ledc_timer = LEDC_TIMER_0;
config.pin_d0 = Y2_GPIO_NUM;
config.pin_d1 = Y3_GPIO_NUM;
config.pin_d2 = Y4_GPIO_NUM;
config.pin_d3 = Y5_GPIO_NUM;
config.pin_d4 = Y6_GPIO_NUM;
config.pin_d5 = Y7_GPIO_NUM;
config.pin_d6 = Y8_GPIO_NUM;
config.pin_d7 = Y9_GPIO_NUM;
config.pin_xclk = XCLK_GPIO_NUM;
config.pin_pclk = PCLK_GPIO_NUM;
config.pin_vsync = VSYNC_GPIO_NUM;
config.pin_href = HREF_GPIO_NUM;
config.pin_sccb_sda = SIOD_GPIO_NUM;
config.pin_sccb_scl = SIOC_GPIO_NUM;
config.pin_pwdn = PWDN_GPIO_NUM;
config.pin_reset = RESET_GPIO_NUM;
config.xclk_freq_hz = 20000000;
config.frame_size = FRAMESIZE_QVGA;
config.pixel_format = PIXFORMAT_JPEG;
config.grab_mode = CAMERA_GRAB_WHEN_EMPTY;
config.fb_location = CAMERA_FB_IN_PSRAM;
config.jpeg_quality = 12;
config.fb_count = 1;

if (psramFound()) {
config.jpeg_quality = 10;
config.fb_count = 2;
config.grab_mode = CAMERA_GRAB_LATEST;
} else {
config.frame_size = FRAMESIZE_VGA;
config.fb_location = CAMERA_FB_IN_DRAM;
}

// Initialize camera
esp_err_t err = esp_camera_init(&config);
if (err != ESP_OK) {
Serial.printf("Camera init failed with error 0x%x", err);
return;
}

WiFi.begin(ssid, password);
Serial.print("Connecting to WiFi");
while (WiFi.status() != WL_CONNECTED) {
delay(500);
Serial.print(".");
}
Serial.println("\n✅ WiFi connected!");

netClient.setInsecure();

Serial.println("Telegram Bot started.");
}

void loop() {
if (millis() - lastCheckTime >= checkInterval) {
checkTelegramBot();
lastCheckTime = millis();
}
}

void checkTelegramBot() {
int numNewMessages = bot.getUpdates(bot.last_message_received + 1);

while (numNewMessages) {
for (int i = 0; i < numNewMessages; i++) {
String chat_id = String(bot.messages[i].chat_id);
String text = bot.messages[i].text;

Serial.print("📨 Received: ");
Serial.println(text);

if (text == "/help") {
String helpMsg = "🤖 Available commands:\n\n";
helpMsg += "/help - Know about all commands\n";
helpMsg += "/about - Know about the bot\n";
helpMsg += "/subscribe - Subscribe to our YouTube channel\n";
helpMsg += "/ask - Ask a question with AI\n";
bot.sendMessage(chat_id, helpMsg, "");

} else if (text == "/about") {
String aboutMsg = "ℹ️ I am an XIAO ESP32S3-powered Telegram Bot! 🚀\n";
aboutMsg += "I can answer your queries using AI and also share resources.";
bot.sendMessage(chat_id, aboutMsg, "");

} else if (text == "/subscribe") {
String subMsg = "🎥 Support us by subscribing to our YouTube channel:\n";
subMsg += "👉 https://www.youtube.com/@roboatticLab";
bot.sendMessage(chat_id, subMsg, "");

} else if (text == "/ask") {
bot.sendMessage(chat_id, "✍️ Send me your query", "");
waitingForQuery = true;

} else if (waitingForQuery) {
waitingForQuery = false;
bot.sendMessage(chat_id, "⏳ Thinking...", "");
String image = handleCapture();
Serial.println(image);

String geminiResponse = callGeminiAPI(text, image);
bot.sendMessage(chat_id, geminiResponse, "");
}
}
numNewMessages = bot.getUpdates(bot.last_message_received + 1);
}
}

Copy and paste this code in the Arduino IDE and upload it!

See the magic...

Wiring the Circuit - Making It Portable

Copy of Copy of Left Leg Servo (2).png
Screenshot (966).png
Screenshot 2025-08-24 090252.png
Screenshot 2025-08-24 090318.png

To make our AI Pin portable, we’ll need a few additional components: a 3.7V Li-Po battery and a small switch. These will power the XIAO ESP32S3 Sense board.

Connect the Battery with a Switch

  1. Solder the negative terminal of the battery directly to the GND pin of the XIAO ESP32S3 Sense board.
  2. Take the positive terminal of the battery and connect it to one side of a switch.
  3. From the other side of the switch, connect a wire to the 3V3 (or VIN) pin on the board.


Default battery charging support

The XIAO ESP32S3 board includes a built-in power management chip for charging a connected lithium battery via its USB-C port.

Here is how the charging functionality works by default:

  1. Charging indicator: A red LED on the board serves as the charging indicator.
  2. Power and charging status:
  3. Board connected to USB without a battery: The red LED will turn on briefly and then turn off after about 30 seconds.
  4. Battery connected and charging via USB: The red LED will flash to indicate that the battery is currently charging.
  5. Battery fully charged: When the battery is full, the red LED will turn off.

Case for It

2cm.png
Screenshot (975).png
Screenshot (967).png
Screenshot (968).png
Screenshot (969).png
Screenshot (970).png
Screenshot (971).png
Screenshot (972).png
Screenshot (973).png
Screenshot (977).png
Screenshot (976).png
Screenshot (978).png
Screenshot (979).png

To construct the case, I will use cardboard, but you can use any material, such as acrylic sheet/sun board, etc., as per your requirement. The PDF file containing the cutout templates is attached below. Please refer to the accompanying images for guidance on assembling the case for this project.

Downloads

AI PIN CUTOUT.pdf

Working Video and Tutorial

How to Make *AI Pin* | Real Life Jarvis (Student Project!)
Screenshot (981).png
Screenshot (982).png
Screenshot (983).png

Congratulations! You’ve successfully built your own AI Pin. A demonstration video of this project can be viewed here: Watch Now

Thank you for your interest in this project. If you have any questions or suggestions for future projects, please leave a comment, and I will do my best to assist you.

For business or promotional inquiries, please contact me via email at Email.

I will continue to update this instructable with new information. Don’t forget to follow me for updates on new projects and subscribe to my YouTube channel (YouTube: roboattic Lab) for more content. Thank you for your support.