Glowing Color-Changing Guitar

In the kingdom of rock and roll it is important to set oneself apart. With millions of people in this world who can play the guitar, simply playing well is just not going to cut it. You need something extra to rise up as a rock god. Consider this guitar the mystical glowing ax bestowed upon you by the Rock Goddess of Bangs; The fabled ax that will lay waste to nonbelievers and shred through the aether with the transcendent glory of rock. With this weapon of unfathomable power, you will be an explosion of light and sound rising up above the writhing masses.

While there are a couple of other glowing guitars out there, this one by and large sets itself apart. For starters, it is frosted to diffuse the glow of the LEDs. This means that the whole body glows instead of being just edge-lit, and you can also see it during the daytime. The other unique feature of this guitar is that it responds to the music being played. The brightness is adjusted by the volume, and the color is controlled by the duration that it is being played. So, the harder you rock, the more colors you will see.

You will need:

(x1) Clear acrylic guitar *
(x1) Arduino Micro
(x1) Addressable 3-color LED strip
(x1) LM741 op-amp
(x2) 2N5457 transistors -- alternate: NTE457
(x1) 10M resistor **
(x2) 2.2M resistor **
(x1) 470K resistor **
(x4) 100K resistor **
(x2) 47K resistor **
(x2) 10K resistor **
(x1) 1K resistor **
(x1) 10uF capacitor ***
(x2) 1uF capacitor ***
(x3) 0.1uF capacitor
(x1) 1N4733A zener diode
(x1) Proto Board
(x1) 3' mono audio cable
(x2) 4 x AA battery holder
(x1) Power jack
(x20) 4-40 x 1/2" bolts
(x1) 6" x 6" x 0.025" glossy stainless steel
(x1) 2-part epoxy
(x1) 12" x 24" x 1/6" sheet of acrylic
(x1) electric guitar string set

* Finding a clear guitar is the tricky bit. Best course of action is to search Amazon or Google.
** Carbon film resistor kit. Only kit necessary for all labeled parts.
*** Electrolytic capacitor kit. Only kit necessary for all labeled parts.

Please note that some of the links on this page contain Amazon affiliate links. This does not change the price of any of the items for sale. However, I earn a small commission if you click on any of those links and buy anything. I reinvest this money into materials and tools for future projects. If you would like an alternate suggestion for a supplier of any of the parts, please let me know.

Wind down each of the tuning machine heads and remove all of the strings.

Fill in any gaps around the acrylic strip with epoxy. This will prevent sand from getting into the channel during sandblasting.

/*
******************************
Glowing Color Changing Guitar
******************************
by Randy Sarafan - 2013

Controls an LED strip based on the playing of a guitar. 

- The intensity of the playing controls the brightness.
- The frequency of intense playing controls the color.

This code uses the Adafruit_NeoPixel library which can be found  here:
https://github.com/adafruit/Adafruit_NeoPixel

For more information and a schematic visit the project page at:
https://www.instructables.com/id/Glowing-Color-Changing-Guitar/

This code is in the Public Domain. 
However, if you find it incredibly useful, buy me a pizza.

*/


// LED strip library
#include <Adafruit_NeoPixel.h>

// Name pin 12 'PIN'
#define PIN 12

// Set the parameters for the LED strip
// I am using the LED strip sold at Radioshack
Adafruit_NeoPixel strip = Adafruit_NeoPixel(30, PIN, NEO_GRB + NEO_KHZ400);

// Set the named of the analog in pin
const int analogInPin = A0;  

// Variable to read the incoming audio on the analog pin
int sensorValue = 0;

// Variable for mapping the incoming audio to a brightness value between 0 and 255
int outputValue = 0;

// Variable used to store the tally of all sampled values
int sensorValue1 = 0;

// The number of audio readings sampled before the LED strip is updated
int sampleSize = 30;

// Keeps a running tally of the samples taken
int additup = 0;

// The rate at which the color goes from blue (0) to red (255)
int colorChangeRate = 3;

// The rate at which the color goes from red (255) to blue (0)
// This must always be less than the colorChangeRate
int colorDecayRate = 2;

// This variable is used to track how frequently the guitar is played loudly.
// As this value increases, the color changes. However, this variable is automatically 
// decreasing while the guitar is not being played.
int addupintensity = 0;

// Used to store rgb values for the LED strip
uint32_t rgbValues;

void setup() {
 
  // Initialize the LED strip and turn it off
  strip.begin();
  strip.show(); 
  
}


void loop() {

  // Read the analog in value:
  sensorValue = analogRead(analogInPin);
  
  
 // The audio wave goes above and below (about) 500
 // If we only read the numbers above 500, only half of the 
 // audio wave would be sampled. This conditional takes the 
 // numbers below 500 and changes them to the appropriate numbers above. 
 // I am setting numbers that are +/-5 from 500 to be 500 to make sure
 // that the LED strip stays at 0 brightness while it is not being played.
 
 if(sensorValue < 500){
   sensorValue = ((500 - sensorValue) + 500);
   if(495 < sensorValue < 505){
     sensorValue = 500;
   }
 }
 
 // Keep a running tally of all of the sensor values read.
 // This tally will be averaged after the sample size number is reached.
 sensorValue1 = sensorValue + sensorValue1;
 
 // Keep track of how many samples have been taken.
 additup = additup + 1;
 
 // Does this when the number of samples taken matches the sampleSize variable
 if(additup == sampleSize){
   
     // Reset the sample count.
     additup = 0;
   
     // Set the sensor value to be the average of the sensor tally divided by the sample size. 
     sensorValue1 = sensorValue1 / sampleSize;
   
     // Map the average sensor value to a number between 0 and 255 for brightness
     outputValue = map(sensorValue1, 500, 1023, 0, 255);  
   
     // If the average sensor reading is above the 700 threshold
     // then increase addupintensity (variable which changes the color)
     if(sensorValue1 > 700){
       addupintensity = addupintensity + colorChangeRate;
     }
     
     // Don't let addupintensity go over 255
     if(addupintensity > 255){
       addupintensity = 255;
     }
     
     
     // Cycles between colors based on the value of addupintensity. 
     // As the number increases from 0 to 255, the color goes from blue, to green, to red.
     
     if(addupintensity < 85) {
       rgbValues =  strip.Color(255 - addupintensity * 3, addupintensity * 3, 0);//blue to green
     } else if(addupintensity < 170) {
       rgbValues =  strip.Color( 0, 255 - (addupintensity - 85) * 3, (addupintensity - 85) * 3); //green to red
     } else{
       rgbValues = strip.Color(0, 0, 255); // Red
     }
     
     // Calls the function to send color values to the strip
     colorWipe(rgbValues);
     
     // Returns the addupintensity variable to 0 (i.e. blue) at the decay rate
     if(addupintensity > colorDecayRate){
       addupintensity = addupintensity - colorDecayRate;
     }
     
     // Reset the average sensor value tally before the next loop
     sensorValue1 = 0;
   } 
}


// Function to send information to the LED strip
void colorWipe(uint32_t c) {
  for(uint16_t i=0; i<strip.numPixels(); i++) {
    
    // Set the color value to each pixel
    strip.setPixelColor(i, c);
    
    // Set the brightness of the LED strip   
    strip.setBrightness(outputValue);

    // Send the color and brightness information to the LED strip
    strip.show();
  }
}

Fasten the strap buttons firmly back in place.

At this point, there is nothing left to do but to turn on the LED display by pressing the power switch and rocking out.

While this guitar is entirely rad - like anything else - it could always be better. Potential improvements include more LEDs, smaller rechargeable LiPo batteries, and adding Arduino frequency detection code to light up different colors for different notes.