Famous Simon Says Game Using Arduino and LEDs

Simon says is a very famous and ubiquitous game. you can find more info about the game Wiki.
In this game, the user has to follow the instructions from the Arduino master. Yes, Arduino will be the Simon master who will tell what has to be done. Sinc, this isan electronic version, Arduino will play a set of lights using LEDs in a sequence. the user has to repeat the sequence. Goodarduinocode.com is the source for this instructable and I would like to share my learnings as well.

The game rules in this game are simple. There will be audio and visual involved making the game entertaining.

1. The Arduino will play a sequence using LED lights (Example: RED, GREEN, RED)
2. The user has to remember the sequence
3. The user will now press the corresponding buttons in the same sequence
4. If the user has pressed the right sequence, the Arduino will play a "Level Up" tone
5. Arduino will now play the next sequence
6. steps 2 to 5 will repeat until the user fails
7. If the user enters the wrong sequence, then the game will end
8. Arduino will play the game over music and restarts the game

Every level up adds a certain level of difficulty in the game.

The wiring is simple and should be easy to follow. The digital output pins of the Arduino are used to drive the LED directly. the resistor is used to limit the current. It is normally okay to have a resistor of 220 Ohms. if you don't have them, you can use the resistors around that value. If the resistor value is too big, the LEDs will be dimmer.

1. Connect Anode of the Yellow LED to the resistor. the other terminal of the resistor shall go to Pin 9 of Arduino.

2. Connect Anode of the Blue LED to the resistor. the other terminal of the resistor shall go to Pin 10 of Arduino.

3. Connect Anode of the Green LED to the resistor. the other terminal of the resistor shall go to Pin 11 of Arduino.

4. Connect Anode of the Red LED to the resistor. the other terminal of the resistor shall go to Pin 12 of Arduino.

5. Connect one end of the push button corresponding to the yellow LED to Pin 2 of Arduino

6. Connect one end of the push button corresponding to Blue LED to Pin 3 of Arduino

7. Connect one end of the push button corresponding to Green LED to Pin 4 of Arduino

8. Connect one end of the push button corresponding to Red LED to Pin 5 of Arduino

9. Connect the ground pin of the buzzer to pin 8 of the Arduino and the positive pin to 5 V.

10. the Arduino ground and 5 V supply should be connected to the breadboard as well. the image is clear in that regard.

The below code is reproduce from the site goodarduinocode.com

I personally doesn't own any part of the code.

/**
Simon Game for Arduino

Copyright (C) 2016, Uri Shaked

Licensed under the MIT License.
*/

#include "pitches.h"

/* Constants - define pin numbers for LEDs,
buttons and speaker, and also the game tones: */
char ledPins[] = {9, 10, 11, 12};
char buttonPins[] = {2, 3, 4, 5};
#define SPEAKER_PIN 8

#define MAX_GAME_LENGTH 100

int gameTones[] = { NOTE_G3, NOTE_C4, NOTE_E4, NOTE_G5};

/* Global variales - store the game state */

byte gameSequence[MAX_GAME_LENGTH] = {0};

byte gameIndex = 0;



/**

Set up the Arduino board and initialize Serial communication
*/
void setup() {
Serial.begin(9600);
for (int i = 0; i < 4; i++) {
pinMode(ledPins[i], OUTPUT);
pinMode(buttonPins[i], INPUT_PULLUP);
}
pinMode(SPEAKER_PIN, OUTPUT);
// The following line primes the random number generator.
// It assumes pin A0 is floating (disconnected):
randomSeed(analogRead(A0));
}

/**
Lights the given led and plays the suitable tone
*/
void lightLedAndPlaySound(byte ledIndex) {
digitalWrite(ledPins[ledIndex], HIGH);
tone(SPEAKER_PIN, gameTones[ledIndex]);
delay(300);
digitalWrite(ledPins[ledIndex], LOW);
noTone(SPEAKER_PIN);
}

/**
Plays the current sequence of notes that the user has to repeat
*/
void playSequence() {
for (int i = 0; i < gameIndex; i++) {
char currentLed = gameSequence[i];
lightLedAndPlaySound(currentLed);
delay(50);
}
}

/**
Waits until the user pressed one of the buttons,
and returns the index of that button
*/
byte readButton() {
for (;;) {
for (int i = 0; i < 4; i++) {
byte buttonPin = buttonPins[i];
if (digitalRead(buttonPin) == LOW) {
return i;
}
}
delay(1);
}
}

/**
Play the game over sequence, and report the game score
*/
void gameOver() {
Serial.print("Game over! your score: ");
Serial.println(gameIndex - 1);
gameIndex = 0;
delay(200);
// Play a Wah-Wah-Wah-Wah sound
tone(SPEAKER_PIN, NOTE_DS5);
delay(300);
tone(SPEAKER_PIN, NOTE_D5);
delay(300);
tone(SPEAKER_PIN, NOTE_CS5);
delay(300);
for (int i = 0; i < 200; i++) {
tone(SPEAKER_PIN, NOTE_C5 + (i % 20 - 10));
delay(5);
}
noTone(SPEAKER_PIN);
delay(500);
}

/**
Get the user input and compare it with the expected sequence.
If the user fails, play the game over sequence and restart the game.
*/
void checkUserSequence() {
for (int i = 0; i < gameIndex; i++) {
char expectedButton = gameSequence[i];
char actualButton = readButton();
lightLedAndPlaySound(actualButton);
if (expectedButton == actualButton) {
/* good */
} else {
gameOver();
return;
}
}
}

/**
Plays an hooray sound whenever the user finishes a level
*/
void levelUp() {
tone(SPEAKER_PIN, NOTE_E4);
delay(150);
tone(SPEAKER_PIN, NOTE_G4);
delay(150);
tone(SPEAKER_PIN, NOTE_E5);
delay(150);
tone(SPEAKER_PIN, NOTE_C5);
delay(150);
tone(SPEAKER_PIN, NOTE_D5);
delay(150);
tone(SPEAKER_PIN, NOTE_G5);
delay(150);
noTone(SPEAKER_PIN);
}

/**
The main game loop
*/
void loop() {
// Add a random color to the end of the sequence
gameSequence[gameIndex] = random(0, 4);
gameIndex++;

playSequence();
checkUserSequence();
delay(300);

if (gameIndex > 0) {
levelUp();
delay(300);
}
}

pitches.h

/**************************************************
* Public Constants
*************************************************/

#define NOTE_B0 31
#define NOTE_C1 33
#define NOTE_CS1 35
#define NOTE_D1 37
#define NOTE_DS1 39
#define NOTE_E1 41
#define NOTE_F1 44
#define NOTE_FS1 46
#define NOTE_G1 49
#define NOTE_GS1 52
#define NOTE_A1 55
#define NOTE_AS1 58
#define NOTE_B1 62
#define NOTE_C2 65
#define NOTE_CS2 69
#define NOTE_D2 73
#define NOTE_DS2 78
#define NOTE_E2 82
#define NOTE_F2 87
#define NOTE_FS2 93
#define NOTE_G2 98
#define NOTE_GS2 104
#define NOTE_A2 110
#define NOTE_AS2 117
#define NOTE_B2 123
#define NOTE_C3 131
#define NOTE_CS3 139
#define NOTE_D3 147
#define NOTE_DS3 156
#define NOTE_E3 165
#define NOTE_F3 175
#define NOTE_FS3 185
#define NOTE_G3 196
#define NOTE_GS3 208
#define NOTE_A3 220
#define NOTE_AS3 233
#define NOTE_B3 247
#define NOTE_C4 262
#define NOTE_CS4 277
#define NOTE_D4 294
#define NOTE_DS4 311
#define NOTE_E4 330
#define NOTE_F4 349
#define NOTE_FS4 370
#define NOTE_G4 392
#define NOTE_GS4 415
#define NOTE_A4 440
#define NOTE_AS4 466
#define NOTE_B4 494
#define NOTE_C5 523
#define NOTE_CS5 554
#define NOTE_D5 587
#define NOTE_DS5 622
#define NOTE_E5 659
#define NOTE_F5 698
#define NOTE_FS5 740
#define NOTE_G5 784
#define NOTE_GS5 831
#define NOTE_A5 880
#define NOTE_AS5 932
#define NOTE_B5 988
#define NOTE_C6 1047
#define NOTE_CS6 1109
#define NOTE_D6 1175
#define NOTE_DS6 1245
#define NOTE_E6 1319
#define NOTE_F6 1397
#define NOTE_FS6 1480
#define NOTE_G6 1568
#define NOTE_GS6 1661
#define NOTE_A6 1760
#define NOTE_AS6 1865
#define NOTE_B6 1976
#define NOTE_C7 2093
#define NOTE_CS7 2217
#define NOTE_D7 2349
#define NOTE_DS7 2489
#define NOTE_E7 2637
#define NOTE_F7 2794
#define NOTE_FS7 2960
#define NOTE_G7 3136
#define NOTE_GS7 3322
#define NOTE_A7 3520
#define NOTE_AS7 3729
#define NOTE_B7 3951
#define NOTE_C8 4186
#define NOTE_CS8 4435
#define NOTE_D8 4699
#define NOTE_DS8 4978

void lightLedAndPlaySound(byte ledIndex)

The function takes the LED number as input, drives it high, Plays the tone and after 300ms, the LED will be turned off.

void playSequence()

Depending on the level of the game, the sequence for the user will be played in this function.

byte readButton()

This function detects any of the input pin which is connected to ground.This is to detect the key which is pressed by the user. The push buttons when pressed, connects the Arduino input pins to ground. Th input pins have pullup enabled in the Arduino code.

void gameOver()

This function will be called when the user fails to enter the exact same sequence as played by the Arduino. This functions plays the game over tone.

void checkUserSequence()

This function will check continuously for the user entered button and the expected button. if the sequence match it will continue the game. if the sequence fail, the gameover fucntion will be called.

This code generates tone with rising pitch to indicate the user that the level has increased by one.

Please refer to this link for more options on tone.

tuning possibilities

1. Increasing or decreasing the amount of time the light will be on
2. Adding time limit for the response from the user
3. Moving or playing around the LED timing gap etc

Arduino Playground - https://wokwi.com/

Software code and connection diagram - https://goodarduinocode.com/

Simon game - https://en.wikipedia.org/wiki/Simon_(game)