Existential Emergency Phone

The Existential Emergency Phone is a multipurpose tool for handling all of life's uncertainties. It can be used for both dialing out and calling in. The way that it works is that when you pick up the handset, the telephone makes a call using a custom cellular module to a list of predefined phone numbers. Whether the phone calls a list of people you know, a list of people you don't know, or randomly dials strangers in your area code, is really up to you. Alternately, the number can be distributed to people with existential emergencies and they can dial in for others to answer. The many manners in which the phone can be used makes it well suited for processing existential emergencies both outgoing and incoming.

Go Get Stuff

You will need:

(x1) red 2500-style no-dial phone
(x1) Arduino Uno
(x1) Cellular Shield
(x1) Ag1170 SLIC
(x1) PCB board
(x4) 1N4004 diodes
(x1) Prepaid SIM card
(x1) BZT03C82 or P6KE82 diode
(x4) 0.1uF ceramic capacitors
(x1) 220uF, 10V, Rubycon ZL capacitor
(x1) 100uF, 6.3v capacitor
(x1) 10uF, 25v capacitor
(x1) 1uF, 25v capacitor
(x1) 10ohm resistor
(x1) 7805 regulator
(x1) quad band antenna
(x1) 6" x 6" x 1/8" acrylic (bracket template below)
(x1) 6" x 6" x 1/8" mat white acrylic (sign template below)
(x1) DC power socket
(x1) 9V / 1A power supply
(x1) Black acrylic paint
(x1) Double-sided tape
(x1) Contact adhesive
(x1) assorted shrink tube
(x1) assorted zip ties
(x1) assorted nuts and bolts (4-40 and 6-32 ideal)
(x1) 22awg wire (stranded - red, black, and green)
(x1) 22awg wire (solid - red, black, and green)

(Note that some of the links on this page are affiliate links. This does not change the cost of the item for you. I reinvest whatever proceeds I receive into making new projects. If you would like any suggestions for alternative suppliers, please let me know.)

Build the Circuit

Build the circuit as drawn in the schematic.

Do not worry yet about connecting wires to external components.

Attach Wires

Attach a 6" stranded red wire to the Vin pin of the 7805 regulator, and a 6" stranded black wire to ground. This will get attached to the power jack.

Connect a 6" solid core red wire to the circuit's 5V rail. Connect a 6" solid core black wire to ground. These will be used to power the Arduino.

Also attach a 6" stranded red wire to the ring pin of the SLIC. Attach a 6" stranded green wire to the tip pin of the SLIC. These wires will be connect to the ring and tip connections on the phone.

Finally, connect a 6" solid core green wire to the F/R pin of the SLIC , another 6" solid core green wire to the RM pin of the SLIC, and a 6" solid core red wire to the SHK pin of the SLIC. These wires will connect to the Arduino to determine the state of the phone receiver and controlling the telephone ringer.

Prepare the Shield

Prepare the cellular shield as outlined in the Arduino Cellular Shield Instructable.

Attach the Antenna

Attach the antenna to the shield by threading the two together.

Audio Wires

Affix shielded audio wires to the board. The inner wire should go to signal. The shielding and outer wire should go to the corresponding signal ground.

Open the Case

Open up the telephone by removing the screws from the bottom of the case.

Disconnect the handset while you are at it.

Remove Brackets

Remove the brackets that are there for potentially holding a dial pad.

This is easily accomplished by drilling through the metal rivets holding them in place.

Wooden Bracket

Download the attached file.

Make a wooden bracket based on this template.

I laser cut mine, but you can get the same results with a jigsaw and a drill.

Drill

Use the bracket to mark mounting holes on the bottom of the case.

Drill through these marks with a 1/8" drill bit.

Mount

Remove the cellular shield from the Arduino.

Affix the Arduino and the circuit board to the bracket using nuts and bolts.

Reattach the Shield

Reconnect the cellular shield to the Arduino.

Wire It Up

Connect the red solid core wire that is connected to the 5V rail on the circuit board is the 5V pin on the Arduino.

Connect the black solid core wire connected to ground on the circuit board to the ground pin on the Arduino.

Connect the green wire connected to the F/R pin on the SLIC to pin 7 on the Arduino.

Connect the green wire connected to the RM pin on the SLIC to pin 8 on the Arduino.

Connect the red wire connected to the SHK pin on the SLIC to pin 12 on the Arduino.

Attach to Case

Using the mounting holes drilled earlier, fasten the wooden bracket to the metal base of the telephone using nuts and bolts.

Make certain that the bolts pass upwards and that the nuts will be located on the inside of the case.

Prep the Jack

Cut the handset jack free from the telephone.

For all four handset wires, leave about an inch to work with. If you keep it too long, you may end up with static or audio interference.

Attach the Jack

Before you start, place shrink tube onto all of the jack's wires and also the shielded audio cables. You will obviously not be able to slide on the shrink tube after it is soldered.

Connect the shielded signal wire from the microphone to the black wire on the jack. Connect the microphone's shielding to the green wire.

Connect the shielded signal wire from the speaker to the red wire on the jack. Connect the speaker's shielding to the white wire.

Slide shrink tube over all of the exposed connections, and shrink it with a heat gun to keep it protected.

Wire the Ringer

On the inside of the telephone, figure out which wire is the green wire coming from the telephone's line jack. Cut this wire, slide some shrink tube over the telephone end (not the jack end), and solder the end connected to the phone to the stranded green wire on the circuit board.

Repeat the same process for the incoming red wire.

Slide the shrink tube over both connections and secure it in place with a heat gun.

Mark and Drill

Make a mark about an inch to the left of the handset jack. The idea here is to install the power jack in a location where it is not going to bump into stuff.

Drill this mark with a 5/16" drill bit.

Power Jack

Remove the power jack's mounting nut, pass it through the hole, and then tightly re-thread the mounting nut.

Paint the Sign

Laser cut and etch the sign if you have not done so already using the attached template. Make sure to leave the acrylic's protective coating on.

If you don't have a laser cutter, cut it out the old fashioned way and then stencil the writing, or create a sticker on transparent printer media.

Anyhow... assuming that you have a laser cutter...

Now is time to paint over the etched writing with black acrylic paint. Put one coat horizontally, wait for it to dry, and put another coat vertically.

When the paint has fully dried, peel off the coating. To remove the coating from the islands inside the letters, you can gently use a toothpick or craft knife, while being careful not to scratch the paint.

Glue the Plate

Coat the front panel of the phone with contact adhesive and the back side of the acrylic panel.

Wait for both to dry.

Align them, and then press them firmly together for a strong bond.

Solder the Power Jack

Solder the black stranded wire from ground on the circuit board to the central terminal on the power jack.

Solder the red stranded wire connected to Vin on the voltage regulator the terminal to the right of the power jack (as pictured).

To be certain that you get it right before connecting it to the circuit board, you may want to plug in the power and test the voltage of these terminals with a multimeter.

Affix the Antenna

Stick the cellular antenna to the backside of the front panel with strong double-sided tape.

Clean Up Wires

It is generally good form not to have a rats nest of wires inside of this thing.

Tidy up the wiring as best you can by zip tying the wires together.

Program the Arduino

Upload the following code to the Arduino:

//**********************************************************************************
// EXISTENTIAL EMERGENCY PHONE
// BY RANYDY SARAFAN
//
// FOR MORE INFO:
// https://www.instructables.com/go/existential/
//
// BUFFERING CODE BASED UPON:
// http://jayeshprojects.blogspot.com/2010/04/real-time-mobile-gps-tracker-with.html
//
// USE THIS CODE HOW YOU WISH
//**********************************************************************************

#include <SoftwareSerial.h>
#define BUFFSIZ 90

char at_buffer[BUFFSIZ];
char buffidx;

int network_registered;
int network_AT_ready;

int firstTimeInLoop = 1;

//List of phone numbers to call
const char *phoneNumbers[5] = {
"ATD2125551212",
"ATD2125551212",
"ATD2125551212",
"ATD2125551212",
"ATD2125551212",
};
 
//Will hold the incoming character from the Serial Port.

char incoming_char=0;

//Create a 'fake' serial port. Pin 2 is the Rx pin, pin 3 is the Tx pin.

SoftwareSerial cell(2,3);  


//for phone module - setting the Arduino pins to variables
int pulsePin = 7;
int ringModePin = 8;
int pickUpPin = 12;

int pickUpState = 0;
int pickedUp = 0;

int stuck = 0;

int x;

// Do system wide initialization here in this function

void setup() {

  //for phone module - pins related to ringing
  pinMode(pulsePin, OUTPUT);
  pinMode(ringModePin, OUTPUT);  // configure i/o pins

  //for phone module - pin related to handset switch
  pinMode(pickUpPin, INPUT);
  
  //Initialize Arduino serial port for debugging.
  Serial.begin(9600);
  
  //Initialize virtual serial port to talk to Phone.
  cell.begin(9600);

  //Let's get started!
  Serial.println("Starting SM5100B Communication...");
  delay(1000);

  /* Currently network is not registered and AT is not ready */
  
  network_registered = 0;
  network_AT_ready = 0;

}

//resets the Arduino when called
void(* resetFunc) (void) = 0;//declare reset function at address 0 


/* Reads AT String from the SM5100B GSM/network Module */

void readATString(void) {

  char c;
  buffidx= 0; // start at begninning
  for (x = 0; x < 10000; x ++) {    
    if(cell.available() > 0) {
      c=cell.read();
      if (c == -1) {
        at_buffer[buffidx] = '\0';
        return;
      }
      if (c == '\n') {
        continue;
      }
      if ((buffidx == BUFFSIZ - 1) || (c == '\r')){
        at_buffer[buffidx] = '\0';
        return;
      }
      at_buffer[buffidx++]= c;
    }
  }
}




/* Processes the AT String to determine if network is registered and AT is ready */

void ProcessATString() {

  if( strstr(at_buffer, "+SIND: 8") != 0 ) {
    network_registered = 0;
    Serial.println("network Network Not Available");
  }

  if( strstr(at_buffer, "+SIND: 11") != 0 ) {
    network_registered=1;
    Serial.println("network Registered");
  }
  
  if( strstr(at_buffer, "+SIND: 4") != 0 ) {
    network_AT_ready=1;
    Serial.println("network AT Ready");
  }
}

 
void loop() {

/* If called for the first time, loop until network and AT is ready */

if(firstTimeInLoop == 1) {

  firstTimeInLoop = 0;
  while (network_registered == 0 || network_AT_ready == 0) {
    readATString();
    ProcessATString();
    }
  }
  
  getPhoneStatus();
  readATString();
  ringingRoutine();
  checkPickup();

}



void getPhoneStatus() {

    cell.println("AT+CPAS");
    delay(500);
    if( strstr(at_buffer, "+CPAS: 0") != 0 ) {
      stuck = 0;
      Serial.println("READY");
     
    }
    if( strstr(at_buffer, "+CPAS: 3") != 0 ) {
      stuck = 0;
      Serial.println("RINGING");
    }
    if( strstr(at_buffer, "+CPAS: 4") != 0 ) {
      stuck = 0;
      Serial.println("IN PROGRESS");
    }
    
    //if not in any of the three states after 20 loops
    if(( strstr(at_buffer, "+CPAS: 0") == 0) && ( strstr(at_buffer, "+CPAS: 3") == 0) && ( strstr(at_buffer, "+CPAS: 4")) == 0) {
      stuck = stuck + 1;
      if(stuck > 20){
           resetFunc(); //call reset  
        }
      }
    
}



//CHECK FOR INCOMING CALLS
void ringingRoutine() {

  if( strstr(at_buffer, "+CPAS: 3") != 0 ) {
    
    digitalWrite(ringModePin, HIGH); 

    for ( int pulses = 0; pulses < 40; pulses++ ){ 
      
      // ring for one second.  
      digitalWrite(pulsePin, HIGH);  // toggle forwardReverse at 20hz (50ms) to get standard USA-style ringing.
      delay(25);
      digitalWrite(pulsePin, LOW);
      delay(25);
      
      pickUpState = digitalRead(pickUpPin);
      if(pickUpState == 1){
        break;
       }
      
     }
     digitalWrite(pulsePin, HIGH);
     digitalWrite(ringModePin, LOW);  // stop ringing. turn ringMode off.
  }
  
}




//CHECK FOR HANDSET PICKUP
//AND ANSWER PHONE OR MAKE CALL
//THEN HANG UP
void checkPickup() {
    pickUpState = digitalRead(pickUpPin);    
    
     //only if this had been ringing!!!
    if(pickUpState == 1){
      if(pickedUp == 0){
        if( strstr(at_buffer, "+CPAS: 3") != 0 ) {
          //Answer the phone
          cell.println("ATA");
          pickedUp = 1;
        }
        if( strstr(at_buffer, "+CPAS: 0") != 0 ) {
          //Make a call
          cell.println(phoneNumbers[random(5)]);
          pickedUp = 1;
        }
      }
    }
    
    
    //if handset placed back on hook, then hang up.
    if(pickUpState == 0){
      if(pickedUp == 1){
        cell.println("ATH");
        pickedUp = 0;
      }
    }
  
}

To change who is getting called take a look at where it says "//List of phone numbers to call."

Put It Back Together

Close the case, reinsert the screws, reattach the handset, and place it back on the hook.

To get started, plug it in, wait a minute or two for the cellular network to initialize, and you should be good to go.

Did you find this useful, fun, or entertaining?
Follow @madeineuphoria to see my latest projects.