Door Lock System
Are you looking to build your own secure, programmable locking system? This project is perfect for learning about electronics, Arduino programming, and creating something practical for everyday use. With this DIY safe-locking mechanism, you can use a 4-digit pin to control a servo motor that locks or unlocks your safe. It's simple to set up, fun to build, and a great way to learn the hardware basics.
Supplies
Assemble the Circuit
Connect the LCD Display
- RS to pin 12
- Enable to pin 11
- D4 to pin 10
- D5 to pin 9
- D6 to pin 8
- D7 to pin 7
Connect the Keypad
- Rows to pins 5,4,3,2
- Columns to pins A3, A2, A1, A0
Attach to Servo Monitor
- Control pin to pin 6
- Power (VCC) and Ground (GND) to the Arduino
Power the Arduino
- Connect via USB to a computer
Code
/* Headers and Libraries */
#include <LiquidCrystal.h>
#include <Keypad.h>
#include <Servo.h>
#include "SafeState.h"
#include "icons.h"
/* Servo Pins and Positions */
#define SERVO_PIN 6
#define SERVO_LOCK_POS 20
#define SERVO_UNLOCK_POS 90
Servo lockServo;
LiquidCrystal lcd(12, 11, 10, 9, 8, 7);
/* Keypad Configuration */
const byte KEYPAD_ROWS = 4;
const byte KEYPAD_COLS = 4;
byte rowPins[KEYPAD_ROWS] = {5, 4, 3, 2};
byte colPins[KEYPAD_COLS] = {A3, A2, A1, A0};
char keys[KEYPAD_ROWS][KEYPAD_COLS] = {
{'1', '2', '3', 'A'},
{'4', '5', '6', 'B'},
{'7', '8', '9', 'C'},
{'*', '0', '#', 'D'}
};
Keypad keypad = Keypad(makeKeymap(keys), rowPins, colPins, KEYPAD_ROWS, KEYPAD_COLS);
SafeState safeState;
/* Lock and Unlock Functions */
void lock() {
lockServo.write(SERVO_LOCK_POS);
safeState.lock();
}
void unlock() {
lockServo.write(SERVO_UNLOCK_POS);
}
/* Startup Message */
void showStartupMessage() {
lcd.setCursor(4, 0);
lcd.print("Welcome!");
delay(1000);
lcd.setCursor(0, 2);
String message = "ArduinoSafe";
for (byte i = 0; i < message.length(); i++) {
lcd.print(message[i]);
delay(100);
}
delay(500);
}
/* Input Secret Code */
String inputSecretCode() {
lcd.setCursor(5, 1);
lcd.print("[____]");
lcd.setCursor(6, 1);
String result = "";
while (result.length() < 4) {
char key = keypad.getKey();
if (key >= '0' && key <= '9') {
lcd.print('*');
result += key;
}
}
return result;
}
*/ Wait Screen */
void showWaitScreen(int delayMillis) {
lcd.setCursor(2, 1);
lcd.print("[..........]");
lcd.setCursor(3, 1);
for (byte i = 0; i < 10; i++) {
delay(delayMillis);
lcd.print("=");
}
}
*/ Set New Code */
bool setNewCode() {
lcd.clear();
lcd.setCursor(0, 0);
lcd.print("Enter new code:");
String newCode = inputSecretCode();
lcd.clear();
lcd.setCursor(0, 0);
lcd.print("Confirm new code");
String confirmCode = inputSecretCode();
if (newCode.equals(confirmCode)) {
safeState.setCode(newCode);
return true;
} else {
lcd.clear();
lcd.setCursor(1, 0);
lcd.print("Code mismatch");
lcd.setCursor(0, 1);
lcd.print("Safe not locked!");
delay(2000);
return false;
}
}
void showUnlockMessage() {
lcd.clear();
lcd.setCursor(0, 0);
lcd.write(ICON_UNLOCKED_CHAR);
lcd.setCursor(4, 0);
lcd.print("Unlocked!");
lcd.setCursor(15, 0);
lcd.write(ICON_UNLOCKED_CHAR);
delay(1000);
}
void safeUnlockedLogic() {
lcd.clear();
lcd.setCursor(0, 0);
lcd.write(ICON_UNLOCKED_CHAR);
lcd.setCursor(2, 0);
lcd.print(" # to lock");
lcd.setCursor(15, 0);
lcd.write(ICON_UNLOCKED_CHAR);
bool newCodeNeeded = true;
if (safeState.hasCode()) {
lcd.setCursor(0, 1);
lcd.print(" A = new code");
newCodeNeeded = false;
}
auto key = keypad.getKey();
while (key != 'A' && key != '#') {
key = keypad.getKey();
}
bool readyToLock = true;
if (key == 'A' || newCodeNeeded) {
readyToLock = setNewCode();
}
if (readyToLock) {
lcd.clear();
lcd.setCursor(5, 0);
lcd.write(ICON_UNLOCKED_CHAR);
lcd.print(" ");
lcd.write(ICON_RIGHT_ARROW);
lcd.print(" ");
lcd.write(ICON_LOCKED_CHAR);
safeState.lock();
lock();
showWaitScreen(100);
}
}
void safeLockedLogic() {
lcd.clear();
lcd.setCursor(0, 0);
lcd.write(ICON_LOCKED_CHAR);
lcd.print(" Safe Locked! ");
lcd.write(ICON_LOCKED_CHAR);
String userCode = inputSecretCode();
bool unlockedSuccessfully = safeState.unlock(userCode);
showWaitScreen(200);
if (unlockedSuccessfully) {
showUnlockMessage();
unlock();
} else {
lcd.clear();
lcd.setCursor(0, 0);
lcd.print("Access Denied!");
showWaitScreen(1000);
}
}
void setup() {
lcd.begin(16, 2);
init_icons(lcd);
lockServo.attach(SERVO_PIN);
Serial.begin(115200);
if (safeState.locked()) {
lock();
} else {
unlock();
}
showStartupMessage();
}
void loop() {
if (safeState.locked()) {
safeLockedLogic();
} else {
safeUnlockedLogic();
}
}
Downloads
Test the System
Startup Screen: Upon powering the Arduino, the LCD will display a welcome message and initialize the system.
Locking and Unlocking:
- Enter a 4-digit PIN on the keypad
- If the PIN matches the saved code, the servo motor will rotate to unlock
- If the PIN is incorrect, the LCD will show an "Access Denied!" message
Changing the Code:
- After unlocking, you can press 'A' to set a new 4-digit PIN
- Confirm the code by re-entering it, and the system will save it
Troubleshooting:
- If the LCD does not light up, check its power and connections
- If the servo does not move, ensure it's connected to PIN 6 and properly powered
Customize
Enhancements
- Add a buzzer to provide audio feedback for correct/incorrect PIN entries
- Use LEDs to indicate lock (red) or unlock (green) states
- Replace the keypad with a fingerprint scanner for added security
Final Notes
Congratulations! You've finally built a fully functional safe-locking mechanism powered by an Arduino. This project not only secures your valuables but also gives you a hands-on experience with programming, wiring, and hardware.
Credit:
https://projecthub.arduino.cc/jayesh_nawani/door-lock-system-with-arduino-54d18a