AVR128DA32 Simple Desktop Clock

This project demonstrates building a simple desktop clock using AVR-DA's RTC and an OLED lcd screen. The clock can be set to the correct time through the use of the 2 buttons connected to MCU port. It also sends the time over one of the CPU UART channels to a desktop PC.

AVR128DA32 adaptor board is at the heart of the project.

It connects to and controls SH1107 OLED display through I2C interface

TTL Serial Port Converter is used to connect CPU to a PC and use it as an extra display

A hardware button is used to set clock to either NORMAL mode or time SET mode

When in SET mode a small star symbol appears at the top of each digit to set (hour;min;sec)

The second hardware button round robins through the digits

If hour is set, it counts from 0 through 23

If minute is set it counts from 0 through 59

If second is set it counts from 0 through 59

Open source acorn micro kernel is used to run several tasks dedicated to respected hardware components

1.OLED task responsible for sending numbers and charactes over I2C protocol to lcd display

oled_sh1107_task:

_THRESHOLD_BARRIER_WAIT InitTasksBarrier,TASKS_NUMBER

_SLEEP_TASK_EXT 255

call sh1107_setup

call sh1107_clear_screen

main_oled:

//render clock

rcall render_oled_hour

rcall render_oled_minute

rcall render_oled_second

rcall render_set_mode //are we in a SET mode

//render Sofia

ldi temp,62

mov XX,temp

ldi temp,84

mov YY,temp

ldi ZH,high(sofia_text*2)

ldi ZL,low(sofia_text*2)

rcall render_rom_text

//render Bulgaria

ldi temp,62

mov XX,temp

ldi temp,100

mov YY,temp

ldi ZH,high(bulgaria_text*2)

ldi ZL,low(bulgaria_text*2)

rcall render_rom_text

call sh1107_send_buffer

_SLEEP_TASK_EXT 2000

call sh1107_clear_buffer

rjmp main_oled

2.RTC task processing interrupt request at every second tick comming from CPU internal RTC clock

rtc_task:

rcall rtc_init

_THRESHOLD_BARRIER_WAIT InitTasksBarrier,TASKS_NUMBER

_INTERRUPT_DISPATCHER_INIT temp,RTC_TASK_ID

rtc_main:

_INTERRUPT_WAIT RTC_TASK_ID

/**skip if button SET is active***/

lds temp,left_right_button

tst temp

brne rtcend

;every second tick

lds temp,second

inc temp

cpi temp,60

breq rtcmin_00

sts second,temp

rjmp rtcend

rtcmin_00:

clr temp ;nulify seconds to start over

sts second,temp

lds temp,minute

inc temp

cpi temp,60

breq rtcmin_01

sts minute,temp

rjmp rtcend

rtcmin_01:

clr temp ;nulify minutes to start over

sts minute,temp

lds temp,hour

inc temp

cpi temp,24

breq rtcmin_02

sts hour,temp

rjmp rtcend

rtcmin_02:

clr temp ;nulify hour to start over

sts hour,temp

rtcend:

_INTERRUPT_END RTC_TASK_ID

rjmp rtc_main

3.Button press task to process interrupt from first HW button and select the mode -

NORMAL - clock is working showing current time

SET - clock is in config mode to set current time

button_select_digit_task:

;input pin

lds temp,PORTC_DIR

cbr temp,(1<<PIN0) ;PORT_INT0_bp

sts PORTC_DIR,temp

;internal pullup enable

lds temp, PORTC_PIN0CTRL

sbr temp, 1<<PORT_PULLUPEN_bp

sts PORTC_PIN0CTRL,temp

;interrupt

lds temp,PORTC_PIN0CTRL

ori temp,PORT_ISC_FALLING_gc

sts PORTC_PIN0CTRL,temp

_THRESHOLD_BARRIER_WAIT InitTasksBarrier,TASKS_NUMBER

_INTERRUPT_DISPATCHER_INIT temp,BUTTON_PRESS_PORTC_ID

main_btn_select_evsys:

_INTERRUPT_WAIT BUTTON_PRESS_PORTC_ID

lds temp,left_right_button

inc temp

cpi temp,4

breq btnsel_00

sts left_right_button,temp

rjmp btnsel_exit

btnsel_00:

clr temp ;set to inactive

sts left_right_button,temp

btnsel_exit:

_INTERRUPT_END BUTTON_PRESS_PORTC_ID

_SLEEP_TASK_EXT 5000

;interrupt enable

lds temp,PORTC_PIN0CTRL

ori temp,PORT_ISC_FALLING_gc

sts PORTC_PIN0CTRL,temp

rjmp main_btn_select_evsys

4.Button press task to process interrupt from second HW button and select the digit to set current clock number

Setting hours digit iterrates from 0 to 23

Setting minutes digit iterrate from 0 to 59

Setting seconds digit iterrate from 0 to 59

button_updown_digit_task:

;input

lds temp,PORTD_DIR

cbr temp,(1<<PIN0) ;PORT_INT0_bp

sts PORTD_DIR,temp

;internal pullup enable

lds temp, PORTD_PIN0CTRL

sbr temp, 1<<PORT_PULLUPEN_bp

sts PORTD_PIN0CTRL,temp

;interrupt

lds temp,PORTD_PIN0CTRL

ori temp,PORT_ISC_FALLING_gc

sts PORTD_PIN0CTRL,temp

_THRESHOLD_BARRIER_WAIT InitTasksBarrier,TASKS_NUMBER

_INTERRUPT_DISPATCHER_INIT temp,BUTTON_PRESS_UPDOWN_PORTD_ID

button_updown_digit_main:

_INTERRUPT_WAIT BUTTON_PRESS_UPDOWN_PORTD_ID

lds temp,left_right_button

tst temp //is SET active

breq butupdo_exit //nothing to do

cpi temp,1 //sec

brne butupdo_10

lds temp,second

inc temp

cpi temp,60

brne butupdo_1

clr temp //start over

butupdo_1:

sts second,temp

rjmp butupdo_exit

butupdo_10:

cpi temp,2 //min

brne butupdo_20

lds temp,minute

inc temp

cpi temp,60

brne butupdo_2

clr temp //start over

butupdo_2:

sts minute,temp

rjmp butupdo_exit

butupdo_20:

cpi temp,3 //hour

brne butupdo_exit

lds temp,hour

inc temp

cpi temp,24

brne butupdo_3

clr temp //start over

butupdo_3:

sts hour,temp

butupdo_exit:

_INTERRUPT_END BUTTON_PRESS_UPDOWN_PORTD_ID

_SLEEP_TASK_EXT 5000

;interrupt enable

lds temp,PORTD_PIN0CTRL

ori temp,PORT_ISC_FALLING_gc

sts PORTD_PIN0CTRL,temp

rjmp button_updown_digit_main

Firmware project is based on acorn micro kernel operating system driving 4 separate tasks

1. Download source code from github repo - clock_rtc_oled
2. Find and open project file clock-rtc-oled.asmproj in Microchip AVR Studio
3. Build project to generate HEX file
4. Flash Hex file using UPDI programmer